Oblivion Game Data

ScriptName MQ15Script
;MQ15

short convStage		; used to track conversation stage
short resurrectBase	; used to set resurrection time for Eternal Garden guys
float speechTimer		; timer for Mankar's speech
short mankarRant		; which rant we're on
short mankarRantDone	; set to 1 when last info of a stage plays
short mankarRantGo		; set to 1 to start ranting

float fQuestDelayTime

Begin Gamemode

; trigger his series of rants
if mankarRantDone == 1 && speechTimer <= 0 && getstage MQ15 < 78
	if mankarRant == 0
		; second one is triggered when player gets distance from start
		if player.getdistance MQ15ParadiseEntryPortal > 10000
			set mankarRant to 1
			set mankarRantGo to 1
			set mankarRantDone to 0
		endif	
	elseif mankarRant == 1
		; third one is triggered when player gets Bands of Chosen
		if player.getitemcount MQ15Bracers > 0
			set mankarRant to 2
			set mankarRantGo to 1
			set mankarRantDone to 0
		endif	
	elseif mankarRant == 2
		; fourth one follows immediately
		set mankarRant to 3
		set mankarRantGo to 1
		set mankarRantDone to 0
		set speechTimer to 5
	elseif mankarRant == 3
		; fifth one is triggered when player enters Flooded Grotto
		if player.getincell ParadiseGrotto01 == 1
			set mankarRant to 4
			set mankarRantGo to 1
			set mankarRantDone to 0
		endif	
	elseif mankarRant == 4
		; sixth one follows immediately
		set mankarRant to 5
		set mankarRantGo to 1
		set mankarRantDone to 0
	endif
	
	if mankarRantGo == 1
		set speechTimer to speechTimer + 3
	endif
endif

if speechTimer > 0
	set speechTimer to speechTimer - getsecondspassed
else
	if mankarRantGo == 1
		Set speechTimer to ( MQ15ResurrectPad1.say MQ15MankarRant 1 MankarCamoran 1 ) + .2
		if mankarRantDone == 1
			set mankarRantGo to 0
		endif
	endif
	; stage 6 when you remove the Bands
;	if getstage MQ15 >= 70 && getstage MQ15 < 75 && mankarRantDone == 0
;		Set speechTimer to ( MQ15ResurrectPad1.say MQ15MankarRant 1 MankarCamoran 1 ) + .2
;	endif

	if getstage MQ15 == 78
		; Mankar's speech to player
		set speechTimer to ( MankarCamoranRef.sayto player MQ15MankarSpeech 1 ) + .2
	endif
endif

;Journal upon entry into Eternal Garden
if getstage MQ15 < 20
	if player.GetInCell Paradise == 1 
		SetStage MQ15 20
	endif
endif

; journal upon entry into Forbidden Grotto
if getstage MQ15 >= 20 && getstage MQ15 < 50
	if player.GetInCell ParadiseGrotto02 == 1
		SetStage MQ15 50
	endif
endif

; player enters cage
if getstage MQ15 == 58 
	if MQ15PlayerCageMarker.getdistance player < 50
		setstage mq15 60
	endif
endif

; journal upon entry into Grotto 03
if getstage mq15 >= 50 && getstage MQ15 < 68
	if player.GetInCell ParadiseGrotto03 == 1
		SetStage MQ15 68
	endif
endif

; trigger Mankar Camoran's speech
if getstage mq15 >= 70 && getstage MQ15 < 78
	if MankarCamoranRef.getdistance player < 525
		setstage MQ15 78
	endif
endif

; trigger journal 80 at end of Camoran's speech
if getstage MQ15 == 79 && speechTimer <= 0
	setstage MQ15 80
endif

if getstage MQ15 == 91
	if speechTimer <= 0
		setstage MQ15 92
	endif
endif

if getstage MQ15 == 90
	if speechTimer <= 0
		setstage MQ15 91
	endif
endif

; player returns to Cloud Ruler
if GetStage MQ15 == 89
	if player.GetInCell CloudRulerTemple == 1
		setstage MQ15 90
	endif
endif


end